This is an old revision of the document!


Sizing sub-language

The sizing sub-language is used to simplify gate sizing specifications. The prs sub-language already provides a mechanism to specify sizing, but this can become very verbose. For example, consider an inverter

prs {
  in => out-
}

Now, if we want the pull-up network to have width 20 units and the pull-down to have width 10 units, this gets turned into:

prs {
  in<10> -> out-
 ~in<20> -> out+
}

Note that the convenience of specifying combinational logic is lost, as two production rules have to be specified to control the sizes of all the gates.

Often all one is interested in is sizing the gates so that they have some unit drive strength, where the unit selected is technology/project specific. The sizing body is the way this can be specified. Suppose the net section of the configuration file specifies that the unit drive strength is 10 lambda, and that the p-to-n ratio is 2. In this case, one can write the following instead:

prs {
  in => out-
}
sizing {
  out {-1}
}

The sizing body is a semi-colon separated list of directives. In the example above, the directive out {-1} specifies that the pull-down network (indicated by -) is to be sized with the drive strength of a unit n-transistor (assumed to be 10 lambda, in our example).

This has the same effect as:

prs {
  in <10> -> out-
 ~in <20> -> out+
}

The p-to-n ratio is automatically used to size the pull-up network differently from the pull-down network.

prs {
  a & b => c-
  ~c => d-
}
sizing {
 c {-1}; d{-1}
}

The example above results in the following sizing:

prs {
  a<20> & b<20> -> c-
  ~a <20> | ~b <20> -> c+
  c <10> -> d-
  ~c <20> -> d+
}

Note that that series transistors are appropriately sized, as are the parallel ones. Note that the default standard length is used for all transistors.

Specifying sizing for a production rule that has manual sizing specified is a warning; in this case, the sizing directive is ignored.

An example of the general form of the sizing directive is:

 sizing {
   out {-5,lvt;2 , +4,lvt;2 }
 }

This says that the pull-down network should be sized with 5 times the drive strength, and all gates should use two fingers and lvt flavor transistors. The pull-up network should be sized with 4 times the unit drive strength, use lvt transistors, and two fingers. The order of the two drive strengths can be interchanged; i.e. this is the same as writing

sizing {
  out {+4,lvt;2 , -5,lvt;2 }
}

If a circuit wants to use a different unit width, that can also be specified as follows:

sizing {
  unit_n 20;
  out {-1};
}

This says that the unit n-transistor is 20 lambda wide.